Exemplo de .tcshrc

########################################################
#         Arquivo  .tcshrc                             #
#						       #
#	     tcsh  6.07.02                             #
#						       #
#        ferrari@if.ufrgs.br  1999                     #
########################################################

# Comentarios comecam com '#'
# Para continuar uma linha na proxima, termine-a com  '\'

# ajusta permissoes de criacao para  rwx------
umask 077



# ++++++ Verifica a arquitetura   ++++++  
# ++ e ajusta as variaveis de acordo +++

if ($?ARCH) unset ARCH
set ARCH = `uname`

if ($ARCH == Linux ) then 
    setenv X11HOME /usr/X11  
    setenv TEXHOME /usr/lib/texmf
else if ($ARCH == SunOS) then 
    setenv X11HOME /usr/local/X11
    setenv TEXHOME /usr/local/tex
endif




# +++++    PATH's      ++++++

setenv MANPATH .:$HOME/util/man:/astrodsk/local/man:/usr/man:\
/usr/local/man:/usr/local/tex/man:$X11HOME/man:/usr/local/f77/man:\
/usr/openwin/share/man 

setenv HPATH $MANPATH

set lpath = ( /bin              \
	      /usr/bin          \
	      /usr/local/bin    \
	      /sbin             \
              /usr/sbin         \
	      $X11HOME/bin      \
	      /opt/kde/bin     	)

set mypath = ( $HOME/util/bin      \
	       $TEXHOME/bin        )

set path = (. $mypath     \
	      $lpath      \
	      /usr/ucb    \
	      /usr/etc    )




#+++++       ajustes para TCSH       +++++
#++ veja o manual do tcsh para detalhes ++
#++             (man tcsh)              ++
 
set prompt="%U%m%u %~ %% "
set prompt3="------> %R "
set correct=all
set autologout=0
set listjobs
set printexitvalue
set rmstar
set matchbeep=never 
set ignore_symlinks
set pushdtohome
set watch=(2 any any)
set history=100
set savehist=500
set ignoreeof
set filec=1
set fignore=(.log .aux .o .toc .tof .lot  .log )
set noclobber

set tperiod=20 
alias periodic w

setenv EDITOR 'vi'
setenv PRINTER psl205
setenv PAGER 'less'



#+++++ ALIASES +++++


alias ff	'find . -name \!* -print'

alias ^L             clear
alias l             'ls -lLF'
alias la            'ls -A'
alias ll            'ls -f'
alias qual          'ls `which \!*`'

alias cp            'cp -i'
alias mv            'mv -i'
alias rm            'rm -i'
alias h             'history \!* | tail  -39 | more'

alias bye            logout





# Fim do arquivo



leon 2008-08-19